label menu,ajoutmenu,ann,change,change2,enreg2
label parentmenu,edition,enreg,quit,impr,open
label save_as,about,new,rien,commence,OK
dim a$,i,j,k,d,d$,NomFichier$,NomPath$,Nom$,a
j=3:k=1:Nom$="Menu1.bas"
a$=chr$(10)+chr$(13)

width 0,450
height 0,280
caption 0,"Codage de Menus Automatique  - "+Nom$

memo 1
bar_both 1
font_size 1,8
font_name 1,"Courier New"
full_space 1

main_menu 2
sub_menu 3:parent 3,2:caption 3,"Fichier"
sub_menu 4:parent 4,2:caption 4,"Edition"
sub_menu 5:parent 5,2:caption 5,"Menus"
sub_menu 6:parent 6,2:caption 6,"?"

sub_menu 7:parent 7,5:caption 7,"Nouveau Menu...":on_click 7,menu
sub_menu 14:parent 14,5:caption 14,"Nouveau Parent Menu":on_click 14,parentmenu
sub_menu 28:parent 28,5:caption 28,"Conmencer à...":on_click 28,commence

sub_menu 15:parent 15,4:caption 15,"Couper          Ctrl+X":on_click 15,edition
sub_menu 16:parent 16,4:caption 16,"Copier           Ctrl+C":on_click 16,edition
sub_menu 17:parent 17,4:caption 17,"Coller             Ctrl+V":on_click 17,edition

sub_menu 19:parent 19,6:caption 19,"A Propos...":on_click 19,about

sub_menu 20:parent 20,3:caption 20,"Nouveau":on_click 20,new
sub_menu 21:parent 21,3:caption 21,"Ouvrir...":on_click 21,open
sub_menu 22:parent 22,3:caption 22,"Enregistrer":on_click 22,enreg
sub_menu 23:parent 23,3:caption 23,"Enregistrer sous...":on_click 23,save_as
sub_menu 24:parent 24,3:caption 24,"Imprimer":on_click 24,impr
sub_menu 25:parent 25,3:caption 25,"Propriétés...":inactive 25
sub_menu 26:parent 26,3:caption 26,"Supprimer le Fichier...":inactive 26
sub_menu 27:parent 27,3:caption 27,"Quitter                              Alt+F4":on_click 27,quit

' invisibles -----------------------------

form 8
hide 8
top 8,150
left 8,200
height 8,120
width 8,238
caption 8,"Ajouter une Menu..."
command_target_is 8

alpha 9
left 9,5
top 9,5
caption 9,"Nom :"+a$+a$+"Parent :"

for i=10 to 11
  edit i:left i,70:top i,j:width i,150
  j=j+26
next i
j=5
for i=12 to 13
  button i:left i,j:top i,55
  j=j+80
next i
caption 12,"Annuler":caption 13,"OK":inactive 13
on_click 12,ann:on_click 13,ajoutmenu
on_change 10,change:on_change 11,change2

' -----------------------------------------------

form 29
hide 29
left 29,100
top 29,100
width 29,200
height 29,100
caption 29,"Commencer à..."
command_target_is 29

alpha 30
left 30,5
top 30,5
caption 30,"Commencer le nombre de menu à :"

spin 31
top 31,20
left 31,5
width 31,130
position 31,k
min 31,k:max 31,100000

j=5
for i=32 to 33
  button i:height i,21:top i,42:left i,j
  j=j+80
next i
caption 32,"Annuler":caption 33,"OK"
on_click 32,ann:on_click 33,OK

end

menu:
show 8:a=8:text 10,"":inactive 13:set_focus 10
if text$(31)="1" then text 11,"1":return
if d=0 then text 11,val(text$(31))-1
return

parentmenu:
item_add 1,"main_menu "+str$(k):k=k+1:d=1
text 11,""
return

ajoutmenu:
hide 8:if d=0 then item_add 1,"main_menu "+str$(k):k=k+1:d=1
item_add 1,"sub_menu "+str$(k)+":parent "+str$(k)+","+str$(val(text$(11)))+":caption "+str$(k)+","+chr$(34)+text$(10)+chr$(34):k=k+1
on_change 11,rien:text 11,"":on_change 11,change2:position 31,k
return

ann:
hide a
return

change:
if (len(text$(10))>0) and (len(text$(11))>0) then active 13
return

change2:
if (numeric(text$(11))=0) then message "Juste les chiffres ou nombres sont accepter !":text 11,""
if (len(text$(10))>0) and (len(text$(11))>0) then active 13
return

edition:
if clicked(15)=1 then clipboard_cut 1
if clicked(16)=1 then clipboard_copy 1
if clicked(17)=1 then clipboard_paste 1
return

enreg:
caption 0,"Codage de Menus Automatique  - Enregistrement":wait 1500
file_save 1,"Menu1.bas"
caption 0,"Codage de Menus Automatique  - Menu1.bas"
return

enreg2:
caption 0,"Codage de Menus Automatique  - Enregistrement":wait 1500
file_save 1,NomFichier$
caption 0,"Codage de Menus Automatique  - "+Nom$
return

rien:
return

impr:
d$="C:\Temp\"
dir_change d$
file_save 1,"C:\Temp\Menu1.txt"
execute_wait "write.exe /p C:\Temp\Menu1.txt"
caption 0,"Codage de Menus Automatique  - Impresion en cour..."
wait 1000
file_delete d$+"Menu1.txt"
caption 0,"Codage de Menus Automatique  - "+Nom$
return

open:
if clicked(21)=1
  open_dialog 28
  filter 28,"Fichier Basic    -  *.bas|*.bas"
  NomFichier$=file_name$(28)
  delete 28
  j=len(NomFichier$)
  NomPath$=""
  Nom$=""
for i=j to 1 step -1
  if (mid$(NomFichier$,i,1)="\")
     NomPath$=mid$(NomFichier$,1,i)
     if (i<j) then Nom$=mid$(NomFichier$,i+1,j-i)
     caption 0,"Codage de Menus Automatique  - "+Nom$
     on_click 22,enreg2:active 25:active 26
     exit_for
  end_if
next i
  if (file_exists(NomFichier$)=1)
   file_load 1,NomFichier$
  end_if
end_if
return

save_as:
save_dialog 29
filter 29,"Fichier Basic    -  *.bas|*.bas"
NomFichier$=file_name$(29)
delete 29
file_save 1,NomFichier$+".bas"
return

about:
message "                            CMA-Menus  2.4.1  -  Copyright © janvier 2010"+a$+a$+"Numéro de Version : 2.4.1"+a$+"Nom du logiciel : Codage de Menus Automatique"+a$+"Surnom : CMA-Menus"+a$+a$+"Auteur du logiciel : Nicolas Maltais"+a$+a$+"Écrit en Panoramic 0.9.17i"+a$+"Français : http://pagesperso-orange.fr/panoramic-language/French/index.html"+a$+"Anglais : http://pagesperso-orange.fr/panoramic-language/index.html"
return

new:
clear 1
text 11,"1"
min 31,1:position 31,1
inactive 13:text 10,""
k=1
return

commence:
show 29

min 31,k:max 31,100000
a=29
return

OK:
hide 29:k=text$(31)
if text$(31)="1" then text 11,"1":return
text 11,val(text$(31))-1
return

quit:
terminate